100 '=== RPN CALC (by Num Kadoma)
110 GOTO *INI
120 '--- KEY
130 "." IF D OR E OR ASC B$=H THEN *K '[.]
140 D=I:IF B$=""LET K$="0."
150 GOTO "#"
160 "`" IF B$=""THEN *EXP '[EXP]
170 IF E OR ASC B$=H THEN *K
180 K$=E$,E=LEN B$+I:GOTO "#"
190 "$" K$="":GOTO "H" '[$]
200 "h" K$=CHR$ (ASC K$ AND &DF) '[a]-[f]
210 "H" IF D OR ASC B$=45THEN *K '[A]-[F]
220 IF ASC B$-H LET K$=H$+B$+K$,B$=""
230 "#" IF B$ THEN 270 '[0]-[9]
240 IF F GOSUB *PUSH:PRINT :GOTO 260
250 PRINT #I,L$;
260 PRINT #I,C$;P$;
270 PRINT K$;:B$=B$+K$,F=O:GOTO *UPX
280 "B" M=LEN B$-I:IF M<O PRINT #I,L$;:F=O:GOTO 340 '[BS]
290 V$=RIGHT$ (B$,I):IF V$="."LET D=O
300 IF V$=E$ LET E=O
310 B$=LEFT$ (B$,M):PRINT CHR$ 8;
320 IF RIGHT$ (B$,I)="-"THEN "B"
330 IF M>O THEN *UPX
340 PRINT #I,C$;P$;"0";CHR$ 29;:GOTO *UPX
350 ";" X=O,F=O:GOTO *C '[CCE]
360 "]" S=X:GOTO *F '[STO]
370 "[" N=S:IF B$ LET F=I '[RCL]
380 GOTO *PUSHV
390 "3" N=PI #:GOTO *PUSHV '[PI]
400 *EXP N=EXP 1# '[EXP]
410 *PUSHV IF F GOSUB *PUSH
420 GOTO *OP1
430 "N" IF B$=""THEN *NEG '[+/-]
440 IF ASC B$=H OR E=LEN B$ THEN *K
450 V$=LEFT$ (B$,E):LOCATE I,3
460 IF MID$ (B$,E+I,I)<>"-"LET B$=V$+"-"+MID$ (B$,E+I,LEN B$):PRINT #I,B$;:GOTO *UPX
470 B$=V$+MID$ (B$,E+2,LEN B$):PRINT #I,B$;" ";CHR$ 8;
480 *UPX C=-I:IF ASC B$=H LET X=VAL ("&"+MID$ (B$,2,LEN B$)):GOTO *K
490 X=VAL B$,C=O:GOTO *K
500 *OP
510 "+" N=Y+X:GOTO *OP2 '[+]
520 "-" N=Y-X:GOTO *OP2 '[-]
530 "*" N=Y*X:GOTO *OP2 '[*]
540 "/" N=Y/X:GOTO *OP2 '[/]
550 "\" N=INT (Y/X):GOTO *OP2 '[\]
560 "M" N=Y-INT (Y/X)*X:GOTO *OP2 '[%]
570 *NEG N=-X:GOTO *OP1
580 "&" GOSUB *HML:P=P AND U,Q=Q AND V,R=R AND W:GOSUB *HEX:GOTO *OP2 '[&]
590 "|" GOSUB *HML:P=P OR  U,Q=Q OR  V,R=R OR  W:GOSUB *HEX:GOTO *OP2 '[|]
600 "^" GOSUB *HML:P=P XOR U,Q=Q XOR V,R=R XOR W:GOSUB *HEX:GOTO *OP2 '[^]
610 "~" N=NOT X:GOTO *OP1 '[~]
620 "<" N=Y*2^INT X:GOTO *OP2 '[<]
630 ">" N=INT (Y/2^INT X):GOTO *OP2 '[>]
640 *FN
650 "S" N=SIN X:GOTO *OP1 '[sin]
660 "C" N=COS X:GOTO *OP1 '[cos]
670 "T" N=TAN X:GOTO *OP1 '[tan]
680 "s" N=ASN X:GOTO *OP1 '[sin-1]
690 "c" N=ACS X:GOTO *OP1 '[cos-1]
700 "t" N=ATN X:GOTO *OP1 '[tan-1]
710 "I" N=HSN X:GOTO *OP1 '[hyp][sin]
720 "O" N=HCS X:GOTO *OP1 '[hyp][cos]
730 "A" N=HTN X:GOTO *OP1 '[hyp][tan]
740 "i" N=AHS X:GOTO *OP1 '[hyp][sin-1]
750 "o" N=AHC X:GOTO *OP1 '[hyp][cos-1]
760 "a" N=AHT X:GOTO *OP1 '[hyp][tan-1]
770 "x" N=RCP X:GOTO *OP1 '[1/x]
780 "L" N=LOG X:GOTO *OP1 '[log]
790 "l" N=LN X:GOTO *OP1 '[ln]
800 "b" N=LOG X/LOG 2#:GOTO *OP1 'CTRL+[log]
810 "X" N=TEN X:GOTO *OP1 '[10^x]
820 "e" N=EXP X:GOTO *OP1 '[e^x]
830 "Q" N=SQU X:GOTO *OP1 '[x^2]
840 "U" N=CUB X:GOTO *OP1 'CTRL+[x^2]
850 "q" N=SQR X:GOTO *OP1 '[ROOT]
860 "u" N=CUR X:GOTO *OP1 '[3ROOT]
870 "!" N=FACT X:GOTO *OP1 '[n!]
880 "D" N=DEG X:GOTO *OP1 '[->DEG]
890 "d" N=DMS X:GOTO *OP1 '[->D.MS]
900 "P" N=Y^X:GOTO *OP2 '[y^x]
910 "R" N=Y ROT X:GOTO *OP2 '[xROOTy]
920 "p" M=Z:X=POL (X,Y),Y=Z,Z=M:GOTO *F '[->r0]
930 "r" M=Z:X=REC (X,Y),Y=Z,Z=M:GOTO *F '[->xy]
940 "J" N=NPR (Y,X):GOTO *OP2 '[P]
950 "j" N=NCR (Y,X):GOTO *OP2 '[@]
960 ":" N=ABS X:GOTO *OP1 'SHIFT+[+/-]
970 "n" N=INT X:GOTO *OP1 '[_]
980 "%" N=Y*X/100:GOTO *OP1 'SHIFT+[x^2]
990 "K" N=X*&400:GOTO *OP1 '[K]
1000 "G" GOSUB *GCD:IF M>O LET N=L  :GOTO *OP2 ELSE *F '[G]
1010 "g" GOSUB *GCD:IF M>O LET N=M/L:GOTO *OP2 ELSE *F '[L]
1020 *GCD M=-1:IF X=O OR Y=O RETURN
1030 L=ABS X,Y=ABS Y,M=L*Y
1040 IF L<Y LET N=Y,Y=L,L=N
1050 IF Y=O RETURN
1060 N=Y,Y=L-INT (L/Y)*Y,L=N:GOTO 1050
1070 *STACK
1080 "," X=O,Y=O,Z=O,T=O,F=O:GOTO *C '[CA]
1090 "'" GOSUB *PUSH:F=O:GOTO *C '[RETURN]
1100 "=" GOTO *F '[=]
1110 "V" N=Y:GOTO *OP2 '[DEL]
1120 "@" GOSUB *PUSH:N=L:GOTO *X '[INS]
1130 "W" N=Y,Y=X:GOTO *X '[^|v]
1140 "(" N=T:GOSUB *PUSH:GOTO *X '[(]
1150 ")" N=Y:GOSUB *POP:T=X:GOTO *X '[)]
1160 *SYS
1170 "v" A=(A+I)*-(A<2):GOSUB *DRG:GOTO *K '[DRG]
1180 "m" B=I-B:GOTO *F '[->HEX]
1190 "0" M=&BFCBF:POKE M,PEEK M XOR &10:M=PEEK M AND &10,G$="1C1C3E7F001408141C1C3E7F001C413E":GOSUB *ICON:GOTO *K 'CTRL+[0]
1200 "1" M=&BFCBF:POKE M,PEEK M XOR &80:M=PEEK M AND &80,G$="00602A2F2F2860000F61202F2B206F03":GOSUB *ICON:GOTO *K 'CTRL+[1]
1210 "F" GOSUB *OFF:GOTO *K '[OFF]/[CTRL]+[OFF]
1220 "Z" IF J<=40THEN *Z '[BASIC]
1230 GOSUB *SOFF:K$="INIT"+W$+"SCRN:W6"+C$:J$="*Z":GOTO *K0
1240 *Z CLS :GOSUB *NRM:GOSUB *SON:END
1250 "_"
1260 "" GOTO *K '(do nothing)
1270 '--- SUB
1280 *PUSH T=Z,Z=Y,Y=X:RETURN
1290 *POP Y=Z,Z=T:RETURN
1300 *HML M=G*G,P=INT (Y/M),U=INT (X/M)
1310 M=INT (Y/G),Q=M-P*G,R=Y-M*G
1320 M=INT (X/G),V=M-U*G,W=X-M*G:RETURN
1330 *HEX N=P*G*G+Q*G+R:RETURN
1340 *DRG ON A GOTO 1360,1370
1350 GRAD   :RETURN
1360 DEGREE :RETURN
1370 RADIAN :RETURN
1380 *ICON GCURSOR (232,7):GPRINT MID$ (G$,I+&10*SGN M,&10):RETURN
1390 *SON  POKE 8192,63:RETURN
1400 *SOFF POKE 8192,62:RETURN
1410 *REV M=785569:POKE M,64OR PEEK M:RETURN
1420 *NRM M=785569:POKE M,-65AND PEEK M:RETURN
1430 *K0 KEY &,K$+"G."+J$+C$:END
1440 *OFF POKE &BFE00,&8,&,&41:CALL &FFFDC:RETURN
1450 '--- INIT
1460 *INI CLS :CLEAR :DEFDBL L-N,P-Z
1470 I=1,C$=CHR$ 13,W$=CHR$ 34,J$="*A"
1480 K=I,J=PEEK 785565:IF J<=40THEN *A
1490 *S GOSUB *SOFF:M=8192,K$="INIT"+W$+"SCRN:W4"+C$+"CLS:PO.M,63:":GOTO *K0
1500 *A GPRINT "7F577D557D577F":LOCATE 2:PRINT "RPN CALC (by Num Kadoma)"
1510 *T T$="2_______B___;'____@__________________M&_()*+_-./##########__<=>?jHHHHHHG___Kg___J_______$___\_^n_hhhhhhG___Kg___J_______$___|_~V
1520 *U U$="____FZ_________F______________v_____________,___________________________________________________01_______________________________SCT_mDlLxW`PqQN[]__IOA__________sct__deXp_3Ru%:__r!ioa_________________b_____U
1530 DIM D$(I):D$(O)=".",P$=":",H$="$"
1540 H=ASC H$,A=I+SGN SIN 360,G=32768
1550 E$="e",Q$=C$+CHR$ 10,R$=Q$+H$
1560 S$="          ",L$=C$+S$+S$+S$+S$
1570 O$=CHR$ O
1580 IF INKEY$ THEN 1580ELSE *R
1590 '--- RESUME (G.*)
1600 * IF P$<>":"GOTO *INI
1610 J=PEEK 785565:IF J>40LET J$="*R":GOTO *S
1620 *R OPEN "SCRN:"FOR OUTPUT AS I
1630 ON ERROR GOTO *ERR:GOTO *P
1640 '--- MAIN
1650 *OP2 GOSUB *POP
1660 *OP1 L=X
1670 *X X=N
1680 *F F=I
1690 *C D=O,E=O
1700 *P CLS :IF B THEN 1720
1710 PRINT #I,T;Q$;Z;Q$;Y;Q$;X;:GOTO 1730
1720 C=10:PRINT #I,H$;RIGHT$ (S$+HEX$ T,C);D$(I-T+INT T);R$;RIGHT$ (S$+HEX$ Z,C);D$(I-Z+INT Z);R$;RIGHT$ (S$+HEX$ Y,C);D$(I-Y+INT Y);R$;RIGHT$ (S$+HEX$ X,C);D$(I-X+INT X);:C=O
1730 B$="":LOCATE
1740 *K K$=INPUT $I,J$=MID$ (T$,ASC K$+I,I)
1750 *J GOTO J$
1760 "2" K$=INPUT $I,J$=MID$ (U$,ASC K$+I,I):GOTO *J
1770 '--- ERROR
1780 *ERR M$="Error."
1790 IF ERN =&14IF C>O LET M$="DispErr.":B=O,C=O ELSE M$="Overflow."
1800 IF ERN =&15LET M$="DivBy0."
1810 PRINT #I,C$;" ";M$;" "
1820 M=ASC INPUT $I:IF M=&C IF C<O LET C=O:RESUME *F ELSE RESUME *P
1830 IF M=O IF ASC INPUT $I=&5THEN 1850 '[BASIC]
1840 GOTO 1820
1850 ON ERROR GOTO 0:RESUME 'debug
1860 '--- HELP
1870 *HELP
1880 "?" F=19:IF GU$ THEN 1960 '[?]
1890 GU$="04027F0204",GD$="10207F2010"
1900 GA$="08082A1C08":GT$="14367F3614"
1910 G1$="040400021F",G2$="1219151512"
1920 G3$="0A1115150A",GX$="11091F1211"
1930 GP$="443C047C44",GR$="10207F0101"
1940 G0$="3E4949493E"
1950 IF K<I LET K=I ELSE IF K>F LET K=F
1960 CLS :ON K GOSUB 2100,2210,2260,2310,2380,2440,2490,2540,2640,2690,2770,2850,2900,2980,3060,3150,3200,3260,3300
1970 M=ASC INPUT $I 'xx
1980 IF M=30IF K>I LET K=K-I:GOTO 1960
1990 IF M=31IF K<F LET K=K+I:GOTO 1960
2000 IF M THEN 1970
2010 M=ASC INPUT $I '00 xx
2020 IF M=62IF K>I LET K=K-5:GOTO 1950
2030 IF M=63IF K<F LET K=K+5:GOTO 1950
2040 IF M=94IF K>I LET K=I:GOTO 1960
2050 IF M=95IF K<F LET K=F:GOTO 1960
2060 IF M=5THEN *F
2070 IF M=4OR M=15GOSUB *OFF
2080 GOTO 1970
2090 *H GOSUB *REV:PRINT #I,LEFT$ (" "+V$+S$+S$+S$+"  ",33);:PRINT USING "<##/##>";K;F:GOTO *NRM
2100 V$="RPN CALC ":GOSUB *H
2110 PRINT #I," -1߰        [ ] | +1߰        [ ]
2120 GCURSOR (102,15):GPRINT GU$
2130 GCURSOR (228,15):GPRINT GD$
2140 PRINT #I," -5߰[SHIFT]+[ ] | +5߰[SHIFT]+[ ]
2150 GCURSOR (102,23):GPRINT GU$
2160 GCURSOR (228,23):GPRINT GD$
2170 PRINT #I," ĳ    [CTRL]+[ ] |     [CTRL]+[ ]
2180 GCURSOR (102,31):GPRINT GU$
2190 GCURSOR (228,31):GPRINT GD$
2200 RETURN
2210 V$=" ƭخ (1/2)":GOSUB *H
2220 PRINT #I,"    [0]-[9],[.] |   e      [EXP]
2230 PRINT #I," 16   [A]-[F] | ̺޳     [+/-]
2240 PRINT #I," 16 ƭخ    [X] | PUSH      [RETURN]
2250 RETURN
2260 V$=" ƭخ (2/2)":GOSUB *H
2270 PRINT #I," ò         [=]
2280 PRINT #I," ޯ߰     [BS]
2290 PRINT #I," ƭخ ر  [CCE]
2300 RETURN
2310 V$="ò ƭخ":GOSUB *H
2320 PRINT #I," Ȳ߱ e    [EXP]
2330 PRINT #I," ݼ        [ ]
2340 GCURSOR ( 54,23):GPRINT GP$
2350 GCURSOR (102,23):GPRINT GP$
2360 PRINT #I," LastX        [INS]
2370 RETURN
2380 V$=" ":GOSUB *H
2390 PRINT #I," x  y     [ ] | x  POP ʷ [DEL]
2400 GCURSOR (102,15):GPRINT GT$
2410 PRINT #I,"          [(] | ٸر        [CA]
2420 PRINT #I,"          [)] |
2430 RETURN
2440 V$="ݻ":GOSUB *H
2450 PRINT #I,"             [+] | ޮ         [/]
2460 PRINT #I," ݻ         [-] |             [\]
2470 PRINT #I," ޮ        [*] | ޮ (SHIFT+T)[%]
2480 RETURN
2490 V$="شݻ":GOSUB *H
2500 PRINT #I," ؾ          [&] | ò         [~]
2510 PRINT #I,"            [|] |
2520 PRINT #I," ʲ÷      [^] |
2530 RETURN
2540 V$="޷ޮ":GOSUB *H
2550 PRINT #I," Ͳγ         [x ] | 10  x ޮ   [10 ]
2560 GCURSOR ( 96,15):GPRINT G2$
2570 GCURSOR (228,15):GPRINT GX$
2580 PRINT #I," د߳ [CTRL]+[x ] | y   x ޮ    [y ]
2590 GCURSOR ( 96,23):GPRINT G2$
2600 GCURSOR (228,23):GPRINT GX$
2610 PRINT #I,"                   | exޮ[SHIFT]+[y ]
2620 GCURSOR (228,31):GPRINT GX$
2630 RETURN
2640 V$="":GOSUB *H
2650 PRINT #I,"        [ln]
2660 PRINT #I," ޮֳ    [log]
2670 PRINT #I," Ƽ[CTRL]+[log]
2680 RETURN
2690 V$="":GOSUB *H
2700 PRINT #I," Ͳγ         [ ]
2710 GCURSOR (102,15):GPRINT GR$
2720 PRINT #I," د߳       [  ]
2730 GCURSOR ( 96,23):GPRINT G3$;O;GR$
2740 PRINT #I," xޮ      [  y]
2750 GCURSOR ( 90,31):GPRINT GX$;O;GR$
2760 RETURN
2770 V$="ݶݽ":GOSUB *H
2780 PRINT #I,"         [sin] | ެ   [sin ]
2790 GCURSOR (228,15):GPRINT G1$
2800 PRINT #I," ֹ         [cos] | ެֹ    [cos ]
2810 GCURSOR (228,23):GPRINT G1$
2820 PRINT #I,"          [tan] | ެ    [tan ]
2830 GCURSOR (228,31):GPRINT G1$
2840 RETURN
2850 V$="ݶݽ (1/2)":GOSUB *H
2860 PRINT #I,"  [hyp][sin]
2870 PRINT #I,"  ֹ [hyp][cos]
2880 PRINT #I,"   [hyp][tan]
2890 RETURN
2900 V$="ݶݽ (2/2)":GOSUB *H
2910 PRINT #I,"  ެ[hyp][sin ]
2920 GCURSOR (162,15):GPRINT G1$
2930 PRINT #I,"  ެֹ [hyp][cos ]
2940 GCURSOR (162,23):GPRINT G1$
2950 PRINT #I,"  ެ [hyp][tan ]
2960 GCURSOR (162,31):GPRINT G1$
2970 RETURN
2980 V$="10ݥ60 ݶ":GOSUB *H
2990 PRINT #I," 10 60  [ D.MS]
3000 GCURSOR ( 30,15):GPRINT GA$
3010 GCURSOR ( 78,15):GPRINT GA$
3020 PRINT #I," 60 10   [ DEG]
3030 GCURSOR ( 30,23):GPRINT GA$
3040 GCURSOR ( 84,23):GPRINT GA$
3050 RETURN
3060 V$="ˮˮ ݶ":GOSUB *H
3070 PRINT #I," (x,y) (x:޳,y:ݶ) [ r ]
3080 GCURSOR ( 36,15):GPRINT GA$
3090 GCURSOR (150,15):GPRINT GA$
3100 GCURSOR (162,15):GPRINT G0$
3110 PRINT #I," (x:޳,y:ݶ) (x,y) [ xy]
3120 GCURSOR (102,23):GPRINT GA$
3130 GCURSOR (150,23):GPRINT GA$
3140 RETURN
3150 V$="  ݻ (1/2)":GOSUB *H
3160 PRINT #I," ޭ  [P] | ؼ [<] |    [_]
3170 PRINT #I," бܾ   [@] | з  [>] | ެ[1/x]
3180 PRINT #I," ޮ [n!] | 1޲ [K] |
3190 RETURN
3200 V$="  ݻ (2/2)":GOSUB *H
3210 PRINT #I," ޯ   [SHIFT]+[+/-]| ޲Ը [G]
3220 PRINT #I," yx߰(SHIFT+x )[%]| ޲[L]
3230 GCURSOR (108,23):GPRINT G2$
3240 PRINT #I,"                       |
3250 RETURN
3260 V$="  οݥ޼":GOSUB *H
3270 PRINT #I," x  ο     [STO]
3280 PRINT #I," ο  PUSH [RCL]
3290 RETURN
3300 V$="":GOSUB *H
3310 PRINT #I," ˮӰ [ HEX] | د  [CTRL]+[0]
3320 GCURSOR ( 72,15):GPRINT GA$
3330 PRINT #I,"  Ӱ  [DRG] | ߰   [CTRL]+[1]
3340 PRINT #I," خ   [BASIC] | ذ[OFF] | [?]
3350 RETURN
3360 *HELPE
3370 *DEVEL '***     ֲ ***
3380 '---  ý
3390 *TST PRINT RIGHT$ ("0"+HEX$ ASC INPUT $1,2);"h ";:GOTO *TST
3400 '--- RENUM
3410 *RENUM CLS :KEY &,"100":INPUT "[RENUM]";V$
3420 O$=CHR$ &,F$=CHR$ &5,B$=O$+F$,C$=CHR$ &D,R$=CHR$ &1C,I$=CHR$ &12
3430 *R0 K$=B$+"L.*J"+C$+R$+I$+"'"+C$+B$:J$="*R1":GOTO *K0
3440 *R1 K$=B$+"RENUM "+V$+C$+B$:J$="*R2":GOTO *K0
3450 *R2 V$=C$+CHR$ &1F+R$+CHR$ &7F+C$,K$=B$+"L.*K"+V$+B$:J$="*ED":GOTO *K0
3460 '--- JUMP TABLE ֳ
3470 '1) *TB1,*TB2  DATA  ݺ
3480 '2) RUN *TBL *T,*U  ޮ  
3490 *TBL RESTORE *TB1:U$="":GOSUB 3570:GOSUB 3570
3500 L$="T",O$=CHR$ &,F$=CHR$ &5,B$=O$+F$,C$=CHR$ &D
3510 *T0 K$=B$+"L.*"+L$+C$+CHR$ &1C+F$+"*"+L$+" ERR.10"+C$+B$,J$="*T1":GOTO *K0
3520 *T1 ON ERROR GOTO *T2:K$="",J$="*"+L$:GOTO *K0
3530 *T2 V$="*"+L$+" "+L$+"$="+CHR$ &22+T$,K$=B$+"STR$ERL+V$"+C$+O$+""+C$+B$,J$="*T3"+C$:GOTO *K0
3540 *T3 IF L$="T"LET L$="U",T$=U$:GOTO *T0
3550 *ED CLS :CLEAR :PRINT "Done.":END
3560 '
3570 T$=U$,U$=""
3580 READ V$:U$=U$+V$:IF V$ THEN 3580ELSE RETURN
3590 *TB1 '0123456789abcdef / keycode
3600 DATA "2_______B___;'__" '0x
3610 DATA "__@_____________" '1x
3620 DATA "_____M&_()*+_-./" '2x  !"
3630 DATA "##########__<=>?" '3x 012
3640 DATA "jHHHHHHG___Kg___" '4x @AB
3650 DATA "J_______$___\_^n" '5x PQR
3660 DATA "_hhhhhhG___Kg___" '6x `ab
3670 DATA "J_______$___|_~V" '7x pqr
3680 DATA ""
3690 *TB2 '0123456789abcdef / keycode
3700 DATA "____FZ_________F" '00 0x
3710 DATA "______________v_" '00 1x
3720 DATA "____________,___" '00 2x  !"
3730 DATA "________________" '00 3x 012
3740 DATA "________________" '00 4x @AB
3750 DATA "________________" '00 5x PQR
3760 DATA "01______________" '00 6x `ab
3770 DATA "________________" '00 7x pqr
3780 DATA "_SCT_mDlLxW`PqQN" '00 8x
3790 DATA "[]__IOA_________" '00 9x
3800 DATA "_sct__deXp_3Ru%:" '00 Ax  
3810 DATA "__r!ioa_________" '00 Bx 
3820 DATA "________b_____U"  '00 Cx 
3830 DATA ""
3840 '--- ݽˮ
3850 *VAR
3860 'A : Ӱ (0=GRA,1=DEG,2=RAD)
3870 'B :ˮӰ (0=DECI, 1=HEX)
3880 'C :<0=ƭخ,>0=HEXˮ,0=
3890 'D : ƭخ ׸
3900 'E :"e"   (0="e" ż)
3910 'F :  ׸,  ߰޽
3920 'G :8000h
3930 'H :ASC H$
3940 'I :1
3950 'J :޳  ݹ
3960 'K :  ߰No.
3970 'L :[DBL]LASTx, OP12 ֳ
3980 'M :[DBL]
3990 'N :[DBL]׼ X  
4000 'O :0
4010 'P :[DBL]ޯĴݻ  bit  ..30
4020 'Q :[DBL]ޯĴݻ  bit29..15
4030 'R :[DBL]ޯĴݻ  bit14.. 0
4040 'S :[DBL]STO/RCL 
4050 'T :[DBL]
4060 'U :[DBL]ޯĴݻ  bit  ..30
4070 'V :[DBL]ޯĴݻ  bit29..15
4080 'W :[DBL]ޯĴݻ  bit14.. 0
4090 'X :[DBL]
4100 'Y :[DBL]
4110 'Z :[DBL]
4120 'B$: ƭخ ޯ̧
4130 'C$:CR
4140 'E$:"e" ޳
4150 'G$: ˮֳ
4160 'H$:16 ݽ ĳ
4170 'J$:KEY0 ެ߻
4180 'K$:  / KEY0 Ӽ
4190 'L$:CR+SPACE*40
4200 'M$:װү
4210 'O$:CHR$ 0
4220 'P$:
4230 'Q$:CR+LF
4240 'R$:CR+LF+H$
4250 'S$:SPACE*10
4260 'T$:ð (1 ޲  ֳ)
4270 'U$:ð (2 ޲  ֳ)
4280 'V$:
4290 'W$:ٸ
4300 'D$():  ˮ 0=".",1=""
4310 '(*) ׸: 0=FALSE / non-0=TRUE
